Unity开发者联盟收藏本站
发帖教程新人必读切换到宽版

 找回密码
 立即注册
Unity开发者联盟»论坛 › 3D Answers 技术讨论 › 技术讨论 Technology Answers › 《Unity Shader 入门精要》从Bulit-in 到URP （HLSL）Ch ...
返回列表 发新帖
查看: 132|回复: 0

《Unity Shader 入门精要》从Bulit-in 到URP （HLSL）Chapter15.2-水波效果

[复制链接]
发表于 2024-7-15 18:00 | 显示全部楼层 |阅读模式
前言：
已经进入“高级篇”啦，但愿大师多多撑持，多多存眷，这将对我发生非常愉悦的正反馈~

“《Unity Shader 入门精要》从Bulit-in 到URP”是一个辅佐Unity Shader学习者以冯乐乐女神《Unity Shader 入门精要》为基础学习用HLSL语言编写URP着色器的案例教学系列。

作者自学能力有限，抛砖引玉，如有建议和问题请各位大佬和同仁交流斧正。
Bulit-in版：
  1. // Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
  2. // Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
  4. Shader ”Unity Shaders Book/Chapter 15/Water Wave” {
  5.         Properties {
  6.                 _Color (”Main Color”, Color) = (0, 0.15, 0.115, 1)
  7.                 _MainTex (”Base (RGB)”, 2D) = ”white” {}
  8.                 _WaveMap (”Wave Map”, 2D) = ”bump” {}
  9.                 _Cubemap (”Environment Cubemap”, Cube) = ”_Skybox” {}
  10.                 _WaveXSpeed (”Wave Horizontal Speed”, Range(-0.1, 0.1)) = 0.01
  11.                 _WaveYSpeed (”Wave Vertical Speed”, Range(-0.1, 0.1)) = 0.01
  12.                 _Distortion (”Distortion”, Range(0, 100)) = 10
  13.         }
  14.         SubShader {
  15.                 // We must be transparent, so other objects are drawn before this one.
  16.                 Tags { ”Queue”=”Transparent” ”RenderType”=”Opaque” }
  17.                
  18.                 // This pass grabs the screen behind the object into a texture.
  19.                 // We can access the result in the next pass as _RefractionTex
  20.                 GrabPass { ”_RefractionTex” }
  21.                
  22.                 Pass {
  23.                         Tags { ”LightMode”=”ForwardBase” }
  24.                        
  25.                         CGPROGRAM
  26.                        
  27.                         #include ”UnityCG.cginc”
  28.                         #include ”Lighting.cginc”
  29.                        
  30.                         #pragma multi_compile_fwdbase
  31.                        
  32.                         #pragma vertex vert
  33.                         #pragma fragment frag
  34.                        
  35.                         fixed4 _Color;
  36.                         sampler2D _MainTex;
  37.                         float4 _MainTex_ST;
  38.                         sampler2D _WaveMap;
  39.                         float4 _WaveMap_ST;
  40.                         samplerCUBE _Cubemap;
  41.                         fixed _WaveXSpeed;
  42.                         fixed _WaveYSpeed;
  43.                         float _Distortion;       
  44.                         sampler2D _RefractionTex;
  45.                         float4 _RefractionTex_TexelSize;
  46.                        
  47.                         struct a2v {
  48.                                 float4 vertex : POSITION;
  49.                                 float3 normal : NORMAL;
  50.                                 float4 tangent : TANGENT;
  51.                                 float4 texcoord : TEXCOORD0;
  52.                         };
  53.                        
  54.                         struct v2f {
  55.                                 float4 pos : SV_POSITION;
  56.                                 float4 scrPos : TEXCOORD0;
  57.                                 float4 uv : TEXCOORD1;
  58.                                 float4 TtoW0 : TEXCOORD2;  
  59.                                 float4 TtoW1 : TEXCOORD3;  
  60.                                 float4 TtoW2 : TEXCOORD4;
  61.                         };
  62.                        
  63.                         v2f vert(a2v v) {
  64.                                 v2f o;
  65.                                 o.pos = UnityObjectToClipPos(v.vertex);
  66.                                
  67.                                 o.scrPos = ComputeGrabScreenPos(o.pos);
  68.                                
  69.                                 o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
  70.                                 o.uv.zw = TRANSFORM_TEX(v.texcoord, _WaveMap);
  71.                                
  72.                                 float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;  
  73.                                 fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
  74.                                 fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
  75.                                 fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
  76.                                
  77.                                 o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);  
  78.                                 o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);  
  79.                                 o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  
  80.                                
  81.                                 return o;
  82.                         }
  83.                        
  84.                         fixed4 frag(v2f i) : SV_Target {
  85.                                 float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
  86.                                 fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
  87.                                 float2 speed = _Time.y * float2(_WaveXSpeed, _WaveYSpeed);
  88.                                
  89.                                 // Get the normal in tangent space
  90.                                 fixed3 bump1 = UnpackNormal(tex2D(_WaveMap, i.uv.zw + speed)).rgb;
  91.                                 fixed3 bump2 = UnpackNormal(tex2D(_WaveMap, i.uv.zw - speed)).rgb;
  92.                                 fixed3 bump = normalize(bump1 + bump2);
  93.                                
  94.                                 // Compute the offset in tangent space
  95.                                 float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
  96.                                 i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;
  97.                                 fixed3 refrCol = tex2D( _RefractionTex, i.scrPos.xy/i.scrPos.w).rgb;
  98.                                
  99.                                 // Convert the normal to world space
  100.                                 bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
  101.                                 fixed4 texColor = tex2D(_MainTex, i.uv.xy + speed);
  102.                                 fixed3 reflDir = reflect(-viewDir, bump);
  103.                                 fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb * _Color.rgb;
  104.                                
  105.                                 fixed fresnel = pow(1 - saturate(dot(viewDir, bump)), 4);
  106.                                 fixed3 finalColor = reflCol * fresnel + refrCol * (1 - fresnel);
  107.                                
  108.                                 return fixed4(finalColor, 1);
  109.                         }
  110.                        
  111.                         ENDCG
  112.                 }
  113.         }
  114.         // Do not cast shadow
  115.         FallBack Off
  116. }
复制代码
URP版：

Unity项目源码：
注意：在URP中GrabPass { ”_RefractionTex” }被打消，我们需要使用unity自带的屏幕空间Opaque贴图，即“_CameraOpaqueTexture”，只需在URP Asset 的Inspector窗口打开下图选项就可以在shader中直接调用。

  1. Shader ”Unlit/Chapter15-WaterWave”
  2. {
  3.     Properties {
  4.                 _Color (”Main Color”, Color) = (0, 0.15, 0.115, 1)
  5.                 _MainTex (”Base (RGB)”, 2D) = ”white” {}
  6.                 _WaveMap (”Wave Map”, 2D) = ”bump” {}
  7.                 _Cubemap (”Environment Cubemap”, Cube) = ”_Skybox” {}
  8.                 _WaveXSpeed (”Wave Horizontal Speed”, Range(-0.1, 0.1)) = 0.01
  9.                 _WaveYSpeed (”Wave Vertical Speed”, Range(-0.1, 0.1)) = 0.01
  10.                 _Distortion (”Distortion”, Range(0, 100)) = 10
  11.         }
  12.     SubShader {
  13.                 // We must be transparent, so other objects are drawn before this one.
  14.                 Tags {”RenderPipeline” = ”UniversalPipeline” ”Queue”=”Transparent” ”RenderType”=”Opaque” }
  15.                
  16.                 // This pass grabs the screen behind the object into a texture.
  17.                 // We can access the result in the next pass as _RefractionTex
  18.                 //GrabPass { ”_RefractionTex” }
  19.                
  20.                 Pass {
  21.                         Tags { ”LightMode”=”UniversalForward” }
  22.                        
  23.                         HLSLPROGRAM
  24.                        
  25.                         #pragma vertex vert
  26.                         #pragma fragment frag
  27.                        
  28.             #include ”Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl”
  29.                     #include ”Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl”
  31.         CBUFFER_START(UnityPerMaterial)
  32.             half4 _Color;
  33.                         float4 _MainTex_ST;
  34.                         float4 _WaveMap_ST;
  35.                         half _WaveXSpeed;
  36.                         half _WaveYSpeed;
  37.                         float _Distortion;       
  38.                         float4 _CameraOpaqueTexture_TexelSize;
  39.         CBUFFER_END
  40.                        
  41.                         TEXTURE2D(_MainTex);                SAMPLER(sampler_MainTex);
  42.             TEXTURE2D(_WaveMap);                SAMPLER(sampler_WaveMap);
  43.             TEXTURE2D(_CameraOpaqueTexture);    SAMPLER(sampler_CameraOpaqueTexture);
  45.             TEXTURECUBE(_Cubemap);              SAMPLER(sampler_Cubemap);
  46.                        
  47.                         struct a2v {
  48.                                 float4 vertex : POSITION;
  49.                                 float3 normal : NORMAL;
  50.                                 float4 tangent : TANGENT;
  51.                                 float4 texcoord : TEXCOORD0;
  52.                         };
  53.                        
  54.                         struct v2f {
  55.                                 float4 pos : SV_POSITION;
  56.                                 float4 scrPos : TEXCOORD0;
  57.                                 float4 uv : TEXCOORD1;
  58.                                 float4 TtoW0 : TEXCOORD2;  
  59.                                 float4 TtoW1 : TEXCOORD3;  
  60.                                 float4 TtoW2 : TEXCOORD4;
  61.                         };
  62.                        
  63.                         v2f vert(a2v v) {
  64.                                 v2f o;
  65.                                
  66.                 VertexPositionInputs positionInputs = GetVertexPositionInputs(v.vertex.xyz);
  67.                 o.pos = positionInputs.positionCS;
  68.                 VertexNormalInputs normalInput = GetVertexNormalInputs(v.normal, v.tangent);
  69.                
  70.                 //o.pos = UnityObjectToClipPos(v.vertex);
  71.                                
  72.                                 o.scrPos = positionInputs.positionNDC;
  73.                                
  74.                                 o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
  75.                                 o.uv.zw = TRANSFORM_TEX(v.texcoord, _WaveMap);
  76.                                
  77.                                 o.TtoW0 = float4(normalInput.tangentWS.x, normalInput.bitangentWS.x, normalInput.normalWS.x, positionInputs.positionWS.x);  
  78.                                 o.TtoW1 = float4(normalInput.tangentWS.y, normalInput.bitangentWS.y, normalInput.normalWS.y, positionInputs.positionWS.y);  
  79.                                 o.TtoW2 = float4(normalInput.tangentWS.z, normalInput.bitangentWS.z, normalInput.normalWS.z, positionInputs.positionWS.z);  
  80.                                
  81.                                 return o;
  82.                         }
  83.                        
  84.                         half4 frag(v2f i) : SV_Target {
  85.                                 float3 positionWS = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
  86.                                 half3 viewDir = normalize(_WorldSpaceCameraPos.xyz - positionWS);
  87.                                 float2 speed = _Time.y * float2(_WaveXSpeed, _WaveYSpeed);
  88.                                
  89.                                 // Get the normal in tangent space
  90.                                 half3 bump1 = UnpackNormal(SAMPLE_TEXTURE2D(_WaveMap, sampler_WaveMap, i.uv.zw + speed)).rgb;
  91.                                 half3 bump2 = UnpackNormal(SAMPLE_TEXTURE2D(_WaveMap, sampler_WaveMap, i.uv.zw - speed)).rgb;
  92.                                 half3 bump = normalize(bump1 + bump2);
  93.                                
  94.                                 // Compute the offset in tangent space
  95.                                 float2 offset = bump.xy * _Distortion * _CameraOpaqueTexture_TexelSize.xy;
  96.                                 i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;
  97.                                 half3 refrCol = SAMPLE_TEXTURE2D( _CameraOpaqueTexture, sampler_CameraOpaqueTexture, i.scrPos.xy/i.scrPos.w).rgb;
  98.                                
  99.                                 // Convert the normal to world space
  100.                                 bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
  101.                                 half4 texColor = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, i.uv.xy + speed);
  102.                                 half3 reflDir = reflect(-viewDir, bump);
  103.                                 half3 reflCol = SAMPLE_TEXTURECUBE(_Cubemap, sampler_Cubemap, reflDir).rgb * texColor.rgb * _Color.rgb;
  104.                                
  105.                                 half fresnel = pow(1 - saturate(dot(viewDir, bump)), 4);
  106.                                 half3 finalColor = reflCol * fresnel + refrCol * (1 - fresnel);
  107.                                
  108.                                 return half4(finalColor, 1);
  109.                         }
  110.                        
  111.                         ENDHLSL
  112.                 }
  113.         }
  114.         FallBack ”Packages/com.unity.render-pipelines.universal/FallbackError”
  115. }
复制代码
效果图：





如有收获，请留下“存眷”和“附和”

本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？立即注册

×
回复

使用道具 举报

返回列表 发新帖
懒得打字嘛，点击右侧快捷回复 【右侧内容，后台自定义】
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|手机版|Unity开发者联盟 ( 粤ICP备20003399号 )

GMT+8, 2024-11-21 21:15 , Processed in 0.100641 second(s), 28 queries .

Powered by Discuz! X3.5 Licensed

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表