Unity空间跳跃效果Shader

123456825

诱导已亮，前方净空，准许跳跃，诸君武运昌隆！

正面视角
https://www.zhihu.com/video/1020458059247874048

环绕视角
https://www.zhihu.com/video/1020458082576531456
妈的，这两个月以来的工作竟然让我对敲代码有了一种疏离感，真的太累了。由衷感谢Unity，感谢辻本良三……啊，还有感谢我女朋友。
这两天随便做的一个小玩具，Shader代码放下面，基本逐句注释了，就不多说了……顺带一提GrabPass这种东西PC上玩玩就好，移动端我貌似记得用不了？（求确认）
最后感谢Lex-DRL的SimplexNoise实现。

1. Shader "Unlit/SpaceJumpArea"
2. {
3.         Properties
4.         {
5.                 //拉扯的力度
6.                 _Jitter ("Jitter", Range(0, 0.1)) = 0.1
7.                 //拉扯的粒度
8.                 _Density("Density", Range(1, 100)) = 50
9.                 //拉扯的频率
10.                 _TimeScale("TimeScale", Range(0, 100)) = 1
11.                 //中心保持平静的区域门槛
12.                 _Threshold("Threshold", Range(0, 1)) = 0.35
13.         }
14.         SubShader
15.         {
16.                 //在所有不透明对象之后绘制，防止出现天空球抓取不到的问题
17.                 Tags { "RenderType"="Transparent" }
18.                 //抓取已渲染的部分到缓存中
19.                 GrabPass { "_SpaceTexture" }
20.                 //裁剪表面，只显示背面
21.                 Cull Front
22.                 LOD 100
24.                 Pass
25.                 {
26.                         CGPROGRAM
27.                         #pragma vertex vert
28.                         #pragma fragment frag
29.                        
30.                         #include "UnityCG.cginc"
31.                         #include "noiseSimplex.cginc"
33.                         struct appdata
34.                         {
35.                                 float4 vertex : POSITION;
36.                                 float2 uv : TEXCOORD0;
37.                         };
39.                         struct v2f
40.                         {
41.                                 float4 vertex : SV_POSITION;
42.                                 float4 modelPos : TEXCOORD2;
43.                         };
45.                         sampler2D _SpaceTexture;
46.                         float _Density;
47.                         float _Jitter;
48.                         float _TimeScale;
49.                         float _Shake;
50.                         float _Threshold;
52.                         v2f vert (appdata v)
53.                         {
54.                                 v2f o;
55.                                 o.vertex = UnityObjectToClipPos(v.vertex);
56.                                 o.modelPos = v.vertex;
57.                                 return o;
58.                         }
59.                        
60.                         fixed4 frag (v2f i) : SV_Target
61.                         {
62.                                 //snoise来自Lex-DRL
63.                                 //2D / 3D / 4D optimised Perlin Noise Cg/HLSL library (cginc) - Unity Forum
64.                                 //https://forum.unity.com/threads/2d-3d-4d-optimised-perlin-noise-cg-hlsl-library-cginc.218372/
65.                                 //获取拉扯幅度分布
66.                                 float noise = snoise(float2(atan(i.modelPos.x / i.modelPos.y) * _Density, _Time.y * _TimeScale));
67.                                 //获取拉扯的方向
68.                                 float3 dir = normalize(float3(0,0,1) - i.modelPos.xyz);
69.                                 float d = abs(dot(dir, normalize(i.modelPos)));
70.                                 //根据拉扯的方向和球心到球面方向的点积，判断拉扯的程度，为中心部分制造一片不需要拉扯的平静区域
71.                                 float needDraw = abs(d - _Threshold);
72.                                 needDraw = needDraw + (1 - step(needDraw, 1)) * needDraw;
73.                                 //拉扯GrabPass里存下的缓存
74.                                 float4 grabuv = ComputeGrabScreenPos(UnityObjectToClipPos(float4(i.modelPos.xyz + dir * noise * _Jitter * needDraw, 1)));
75.                                 float4 col = tex2Dproj(_SpaceTexture, grabuv);
76.                                 return float4(col.xyz, 1);
77.                         }
78.                         ENDCG
79.                 }
80.         }
81. }

复制代码

Github地址：